----------
X-Sun-Data-Type: text
X-Sun-Data-Description: text
X-Sun-Data-Name: text
X-Sun-Charset: us-ascii
X-Sun-Content-Lines: 39
Hi Managers, I was to much in a hurry to get an answer that I did not
look to the man pages. Sorry. The man pages describe:
cm_lookup, cm_insert, and cm_delete
All these routine do what I need. I've include a very simple csh script
to allow a person to interface from prompts. We are going to use this
script to schedule the use of a comference room.
Original Message:
>
> Hi Managers!
>
> Does anyone know of a tool to interface with the
> Openwindows Calendar Manager files via a Non X Display Terminal?
> (ex. VT100 Terminal).
Thanks to the following who responded:
Scott Galloway <sdg@assist.mil>
bill@tieman.inteleq.com (Bill McSephney)
sdr@rdga3.att.com (S. D. Raffensberger 52882 (RD))
stern@sunrise.East.Sun.COM (Hal Stern - NE Area Systems Engineer)
adettric@fsaia.qld.gov.au (Alan Dettrick)
Mike Rembis <ebumfr@ebu.ericsson.se>
Kevin.Sheehan@uniq.com.au (Kevin Sheehan {Consulting Poster Child})
jeffw@jane.tiac.net (Jeff Wasilko)
bamby@Scorpio.Com (Yehuda Bamnolker)
apr@wipinfo.soft.net (Sanjeev Jahagirdar )
blymn@awadi.com.AU (Brett Lymn)
bern@TI.Uni-Trier.DE (Jochen Bern)
u2is9gef@gregsun.crrel.usace.army.mil (GREGOR E FELLERS )
"Douglas L. Acker" <dla%se05@se01.wg2.waii.com>
fgreco@lehman.com (Frank Greco)
barnum@fantasia.crd.ge.com (Maria A. Barnum)
Boyd Fletcher <boyd@ccpo.odu.edu>
guy@netapp.com (Guy Harris)
Mark.McIntosh@Engr.uvic.ca
Glenn.Satchell@uniq.com.au (Glenn Satchell - Uniq Professional Services)
Andy_Feldt@phyast.nhn.uoknor.edu (Andy Feldt)
jayl@lattice.com (Jay Lessert)
----------
X-Sun-Data-Type: cshell-script
X-Sun-Data-Description: cshell-script
X-Sun-Data-Name: schedule
X-Sun-Charset: us-ascii
X-Sun-Content-Lines: 90
#!/bin/csh -f
#
# This tool is used to schedule the TTE via a dumb terminal
#
# Written by John Cieply
# Date: 4/6/95
setenv PATH /usr/openwin/bin:/usr/ucb:/usr/bin
set CAL=tte@sunglasses.hrb.com
echo "TTE scheduler"
echo ""
#
# Show the current Schedule for this date
#
date:
echo "Enter the date you would like to use the TTE:"
echo -n "Enter Date (mm/dd/yy): "
set DATE=$<
if ("$DATE" == "") goto date
clear
cm_lookup -c $CAL -d $DATE
#
# Ask if they still want to schedule
#
begin:
echo ""
echo "Do you want to schedule the TTE for $DATE ?"
echo -n "Enter (y/n)"
set RESP=$<
if (("$RESP" == "n") || ("$RESP" == "N")) goto done
#
# Ask for all the information
#
echo -n "Enter Starting Time (HH:MM): "
set START=$<
echo -n "Enter Ending Time (HH:MM): "
set END=$<
echo -n "Enter your name as POC: "
set POC=$<
echo "Enter the type of use for the TTE (Training,Customer Brief,Vendor Demo)"
echo -n "Enter usage information: "
set USE=$<
echo -n "Enter extra information: "
set EXTRA=$<
#
# Display all the information and ask for verification
#
clear
echo "Entered Information"
echo " Date: $DATE"
echo " From: $START"
echo " To: $END"
echo " For: $POC"
echo " $USE"
echo " $EXTRA"
echo ""
echo "Is this information correct?"
echo -n "Enter (y/n)"
set RESP=$<
if (("$RESP" == "n") || ("$RESP" == "N")) goto begin
echo "Do you want this information filed?"
echo -n "Enter (y/n)"
set RESP=$<
if (("$RESP" == "n") || ("$RESP" == "N")) goto done
#
# insert the data into the calendar
#
clear
set WHAT="POC: $POC \nFOR: $USE\n $EXTRA"
cm_insert -c $CAL -d $DATE -s $START -e $END -w $WHAT
#
# Mail information to the TTE staff
#
echo "The TTE has been schduled for" >/tmp/schedule.tte
echo " Date: $DATE" >>/tmp/schedule.tte
echo " From: $START" >>/tmp/schedule.tte
echo " To: $END" >>/tmp/schedule.tte
echo " For: $POC" >>/tmp/schedule.tte
echo " $USE" >>/tmp/schedule.tte
echo " $EXTRA" >>/tmp/schedule.tte
#
mail -s "TTE Scheduled" tte_staff@sunglasses.hrb.com </tmp/schedule.tte
rm /tmp/schedule.tte
#
# Finished
#
done:
echo "Thank You for using the TTE On-Line Scheduler"
This archive was generated by hypermail 2.1.2 : Fri Sep 28 2001 - 23:10:21 CDT